Added TAP reporter and synonyms

jgebal · Mar 19, 2026 · Jul 10, 2025 · Jul 10, 2025 · Jul 11, 2025 · Jul 11, 2025
commit 933f41a70510a04c2eef89846301458009a312e8
diff --git a/source/create_grants.sql b/source/create_grants.sql
@@ -104,6 +104,7 @@ grant execute on &&ut3_owner..ut_tfs_junit_reporter to &ut3_user;
 grant execute on &&ut3_owner..ut_documentation_reporter to &ut3_user;
 grant execute on &&ut3_owner..ut_sonar_test_reporter to &ut3_user;
 grant execute on &&ut3_owner..ut_realtime_reporter to &ut3_user;
+grant execute on &&ut3_owner..ut_tap_reporter to &ut3_user;
 --reporters - coverage
 grant execute on &&ut3_owner..ut_coverage_html_reporter to &ut3_user;
 grant execute on &&ut3_owner..ut_coverage_sonar_reporter to &ut3_user;

diff --git a/source/create_synonyms.sql b/source/create_synonyms.sql
@@ -119,6 +119,7 @@ create &action_type. synonym &ut3_user.ut_tfs_junit_reporter for &&ut3_owner..ut
 create &action_type. synonym &ut3_user.ut_documentation_reporter for &&ut3_owner..ut_documentation_reporter;
 create &action_type. synonym &ut3_user.ut_sonar_test_reporter for &&ut3_owner..ut_sonar_test_reporter;
 create &action_type. synonym &ut3_user.ut_realtime_reporter for &&ut3_owner..ut_realtime_reporter;
+create &action_type. synonym &ut3_user.ut_tap_reporter for &&ut3_owner..ut_tap_reporter;
 --reporters - coverage
 create &action_type. synonym &ut3_user.ut_coverage_html_reporter for &&ut3_owner..ut_coverage_html_reporter;
 create &action_type. synonym &ut3_user.ut_coverage_sonar_reporter for &&ut3_owner..ut_coverage_sonar_reporter;

diff --git a/source/reporters/ut_tap_reporter.tpb b/source/reporters/ut_tap_reporter.tpb
@@ -0,0 +1,104 @@
+create or replace type body ut_tap_reporter is
+
+
+  constructor function ut_tap_reporter(self in out nocopy ut_tap_reporter) return self as result is
+  begin
+    self.init($$plsql_unit);
+    self.lvl := 0;
+    return;
+  end ut_tap_reporter;
+
+  overriding member procedure before_calling_suite(self in out nocopy ut_tap_reporter, a_suite ut_logical_suite) as
+  begin
+    self.print_text('# Subtest: ' || coalesce(a_suite.description, a_suite.name));
+    lvl := lvl + 2;
+    self.print_text('1..' || a_suite.items.count);
+  end before_calling_suite;
+
+  overriding member procedure after_calling_test(self in out nocopy ut_tap_reporter, a_test ut_test) as
+    l_message varchar2(4000);
+    l_test_name varchar2(300) := coalesce(a_test.description, a_test.name);
+
+    procedure print_failed_expectation(a_test ut_test) is
+      l_lines  ut_varchar2_list;
+      l_failed boolean;
+    begin
+      if a_test.get_error_stack_traces().count = 0 then
+        -- If no error occurred, print failed expectation
+        l_lines := a_test.all_expectations(a_test.all_expectations.last).get_result_lines();
+        l_failed := a_test.all_expectations(a_test.all_expectations.last).status >= ut_utils.gc_success;
+        if l_failed then
+          self.print_text('message: ''' || l_lines(1) || '''');
+          self.print_text('severity: fail');
+        end if;
+      else
+        -- Print multi-line YAML-String with implicit newline characters
+        self.print_text('message: |');
+        self.lvl := self.lvl + 1;
+        self.print_text(ut_utils.table_to_clob(a_test.get_error_stack_traces()));
+        self.lvl := self.lvl - 1;
+        self.print_text('severity: error');
+      end if;
+    end print_failed_expectation;
+
+  begin
+
+    if a_test.result = ut_utils.gc_disabled then
+      self.print_text('ok - ' || l_test_name || ' # SKIP'|| 
+        case when a_test.disabled_reason is not null
+          then ': '||a_test.disabled_reason
+          else null
+        end );
+    elsif a_test.result = ut_utils.gc_success then
+      self.print_text('ok - ' || l_test_name);
+    elsif a_test.result > ut_utils.gc_success then
+      if self.lvl = 0 then
+        self.print_text(ut_ansiconsole_helper.red('not ok') || ' - ' || l_test_name);
+      else
+        self.print_text('not ok - ' || l_test_name);
+      end if;
+      self.lvl := self.lvl + 1;
+      self.print_text('---');
+      print_failed_expectation(a_test);
+      self.print_text('...');
+      self.lvl := self.lvl - 1;
+    end if;
+
+  end after_calling_test;
+
+  overriding member procedure after_calling_before_all(self in out nocopy ut_tap_reporter, a_executable in ut_executable) is
+  begin
+    if a_executable.serveroutput is not null and a_executable.serveroutput != empty_clob() then
+      self.print_clob(a_executable.serveroutput);
+    end if;
+  end after_calling_before_all;
+
+  overriding member procedure after_calling_suite(self in out nocopy ut_tap_reporter, a_suite ut_logical_suite) as
+    l_suite_name varchar2(300) := coalesce(a_suite.description, a_suite.name);
+  begin
+    lvl := lvl - 2;
+    if lvl = 0 then
+      if a_suite.result = ut_utils.gc_success then
+        self.print_text('ok - ' || l_suite_name);
+      elsif a_suite.result > ut_utils.gc_success then
+        self.print_text(ut_ansiconsole_helper.red('not ok') || ' - ' || l_suite_name);
+      end if;
+
+      self.print_text(' ');
+    end if;
+
+  end after_calling_suite;
+
+  overriding member procedure before_calling_run(self in out nocopy ut_tap_reporter, a_run in ut_run) as
+  begin
+    self.print_text('TAP version 14');
+    self.print_text('1..' || a_run.items.count);
+    self.print_text(' ');
+  end before_calling_run;
+
+  overriding member procedure after_calling_run(self in out nocopy ut_tap_reporter, a_run in ut_run) as
+  begin
+    self.lvl := 0;
+  end;
+end;
+/
diff --git a/source/reporters/ut_tap_reporter.tps b/source/reporters/ut_tap_reporter.tps
@@ -0,0 +1,13 @@
+create or replace type ut_tap_reporter under ut_documentation_reporter(
+
+  constructor function ut_tap_reporter(self in out nocopy ut_tap_reporter) return self as result,
+  overriding member procedure before_calling_suite(self in out nocopy ut_tap_reporter, a_suite ut_logical_suite),
+  overriding member procedure after_calling_test(self in out nocopy ut_tap_reporter, a_test ut_test),
+  overriding member procedure after_calling_before_all (self in out nocopy ut_tap_reporter, a_executable in ut_executable),
+  overriding member procedure before_calling_run(self in out nocopy ut_tap_reporter, a_run in ut_run),
+  overriding member procedure after_calling_suite(self in out nocopy ut_tap_reporter, a_suite ut_logical_suite),
+  overriding member procedure after_calling_run(self in out nocopy ut_tap_reporter, a_run in ut_run)
+
+)
+not final
+/