-
Notifications
You must be signed in to change notification settings - Fork 372
Expand file tree
/
Copy pathbuild.gradle
More file actions
223 lines (200 loc) · 8.1 KB
/
Copy pathbuild.gradle
File metadata and controls
223 lines (200 loc) · 8.1 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
/*
* Copyright (C) 2017. Uber Technologies
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
import net.ltgt.gradle.errorprone.CheckSeverity
buildscript {
repositories {
mavenCentral()
google() // For Gradle 4.0+
}
dependencies {
classpath libs.android.gradle.plugin
classpath libs.gradle.maven.publish.plugin
}
}
plugins {
alias(libs.plugins.spotless)
alias(libs.plugins.errorprone) apply false
alias(libs.plugins.shadow) apply false
alias(libs.plugins.jmh) apply false
alias(libs.plugins.shellcheck)
}
ext {
oldestErrorProneVersion = libs.versions.errorProneOldest.get()
errorProneJdk17Version = libs.versions.errorProneJdk17.get()
}
repositories {
// to get the google-java-format jar and dependencies
mavenCentral()
}
def currentJavaVersion = JavaVersion.current()
if (!currentJavaVersion.isCompatibleWith(JavaVersion.VERSION_21)) {
throw new GradleException(
"NullAway only builds on JDK 21 or higher now. Detected ${System.getProperty('java.version')}. Please upgrade to JDK 21 or later."
)
}
if (currentJavaVersion == JavaVersion.VERSION_21) {
def runtimeVersion = Runtime.version()
if (runtimeVersion.feature() == 21 && runtimeVersion.update() < 8) {
throw new GradleException(
"Building NullAway on JDK 21 requires at least 21.0.8, but found ${runtimeVersion}. Please upgrade to 21.0.8 or later, or to the most recent JDK release."
)
}
}
subprojects { project ->
project.apply plugin: "net.ltgt.errorprone"
project.dependencies {
errorprone libs.error.prone.core
}
project.tasks.withType(JavaCompile) {
dependsOn(installGitHooks)
// Always compile using the latest JDK we can
javaCompiler = javaToolchains.compilerFor {
languageVersion = JavaLanguageVersion.of(27)
}
options.compilerArgs += [
"-Xlint:deprecation",
"-Xlint:rawtypes",
"-Xlint:unchecked",
"-Werror",
"-parameters",
]
options.errorprone {
// https://github.com/uber/NullAway/issues/1398
check("MisformattedTestData", CheckSeverity.OFF)
// this check is too noisy
check("StringSplitter", CheckSeverity.OFF)
// https://github.com/google/error-prone/issues/3366
check("CanIgnoreReturnValueSuggester", CheckSeverity.OFF)
// turn up various checks
check("WildcardImport", CheckSeverity.ERROR)
check("MissingBraces", CheckSeverity.ERROR)
check("TypeToString", CheckSeverity.ERROR)
check("SymbolToString", CheckSeverity.ERROR)
check("MultipleTopLevelClasses", CheckSeverity.ERROR)
check("ClassName", CheckSeverity.ERROR)
check("PackageLocation", CheckSeverity.ERROR)
check("UnnecessaryAnonymousClass", CheckSeverity.ERROR)
check("UnusedException", CheckSeverity.ERROR)
check("UnnecessaryFinal", CheckSeverity.ERROR)
check("PreferredInterfaceType", CheckSeverity.ERROR)
check("AnnotationPosition", CheckSeverity.ERROR)
check("VoidMissingNullable", CheckSeverity.ERROR)
check("EqualsMissingNullable", CheckSeverity.ERROR)
// To enable auto-patching, uncomment the line below, replace [CheckerName] with
// the checker(s) you want to apply patches for (comma-separated), and above, disable
// "-Werror"
// errorproneArgs.addAll("-XepPatchChecks:[CheckerName]", "-XepPatchLocation:IN_PLACE")
}
}
// We need to use the older sourceCompatibility / targetCompatibility settings, rather than the newer "release"
// option, since we use internal javac APIs, which "release" doesn't allow
tasks.withType(JavaCompile) {
java.sourceCompatibility = JavaVersion.VERSION_17
java.targetCompatibility = JavaVersion.VERSION_17
}
// Javadoc runs in a separate process, so it does not inherit --add-exports options from JavaCompile.
// These exports are needed when documented APIs refer to javac internals.
tasks.withType(Javadoc).configureEach {
// Many subprojects contain intentionally minimal test fixtures and samples. Keep doclint
// enabled for malformed documentation, but do not require API documentation for every
// public fixture member.
options.addBooleanOption("Xdoclint:all,-missing", true)
options.addMultilineStringsOption("-add-exports").setValue([
"jdk.compiler/com.sun.tools.javac.code=ALL-UNNAMED",
"jdk.compiler/com.sun.tools.javac.processing=ALL-UNNAMED",
"jdk.compiler/com.sun.tools.javac.tree=ALL-UNNAMED",
"jdk.compiler/com.sun.tools.javac.util=ALL-UNNAMED",
])
}
tasks.withType(Test).configureEach {
maxParallelForks = Runtime.runtime.availableProcessors().intdiv(2) ?: 1
// A failed test has to be diagnosable from the console alone: CI runs `./gradlew build`
// and publishes no test report, so the log is all a reader gets. Gradle's default logging
// names the exception class and the line of the test method and drops the message, which
// for a NullAway compilation test throws away the entire diagnosis.
testLogging {
exceptionFormat = 'full'
// The top-level settings above configure the lifecycle log level only, so a run under
// --quiet, as agents make, would otherwise report a failure count and nothing else.
quiet {
events 'failed'
exceptionFormat = 'full'
}
}
}
repositories {
mavenCentral()
google()
}
// Spotless complains when applied to the folders containing projects
// when they do not have a build.gradle file
if (project.name != "jar-infer" && project.name != "library-model" && project.name != "jdk-annotations" && project.name != "nullaway-bom" && project.name != "code-coverage-report") {
project.apply plugin: "com.diffplug.spotless"
spotless {
java {
googleJavaFormat(libs.versions.google.java.format.get())
}
}
}
}
spotless {
predeclareDeps()
groovyGradle {
target '**/*.gradle'
greclipse()
leadingTabsToSpaces(4)
trimTrailingWhitespace()
endWithNewline()
}
}
spotlessPredeclare {
java { googleJavaFormat(libs.versions.google.java.format.get()) }
groovyGradle {
greclipse()
}
}
shellcheck {
useDocker = false
shellcheckBinary = "shellcheck"
sourceFiles =
fileTree(".") {
include("**/*.sh")
}
}
////////////////////////////////////////////////////////////////////////
//
// Google Java Format pre-commit hook installation
//
// The hook goes into `.git/hooks`, which exists only where `.git` is a directory. A linked worktree
// has a `.git` file naming that worktree's git directory instead, and a source archive has no
// `.git` at all; a `Copy` task pointed at either one fails validation. A worktree loses no hook by
// being skipped, since git runs the hooks of the shared repository that the main checkout installs
// into.
def dotGitDir = file('.git')
def gitHooksDir = dotGitDir.isDirectory() ? new File(dotGitDir, 'hooks') : null
tasks.register('installGitHooks', Copy) {
from(file('config/hooks/pre-commit-stub')) {
rename 'pre-commit-stub', 'pre-commit'
}
if (gitHooksDir == null) {
enabled = false
} else {
into gitHooksDir
}
filePermissions {
unix(0777)
}
}