Repository navigation
Expand file tree
/
Copy pathCMakeLists.txt
More file actions
178 lines (155 loc) · 6.65 KB
/
Copy pathCMakeLists.txt
File metadata and controls
178 lines (155 loc) · 6.65 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
# SPDX-License-Identifier: GPL-3.0-only
##
# @file CMakeLists.txt
#
# @copyright Copyright (C) 2013-2024 srcML, LLC. (www.srcML.org)
#
# CMake files for building the parser
# parser debugging
option(SRCML_DEBUG_PARSER "Enable parser debugging output" OFF)
# TinySHA1 external include
include(FetchContent)
FetchContent_Declare(TinySHA1
GIT_REPOSITORY https://github.com/mohaps/tinysha1
GIT_TAG 2795aa8de91b1797defdfbff61ed93b22b5ced81
GIT_SHALLOW TRUE
)
FetchContent_MakeAvailable(TinySHA1)
add_library(TinySHA1 INTERFACE IMPORTED)
target_include_directories(TinySHA1 INTERFACE ${tinysha1_SOURCE_DIR})
find_package(LibXml2 REQUIRED)
find_package(Iconv REQUIRED)
find_package(Java COMPONENTS Runtime REQUIRED)
# Setup ANTLR 2.7 library
include(FetchContent)
FetchContent_Declare(antlrsrc
URL https://www.antlr2.org/download/antlr-2.7.7.tar.gz
URL_HASH MD5=01cc9a2a454dd33dcd8c856ec89af090
)
# Fetch the content using previously declared details
FetchContent_MakeAvailable(antlrsrc)
# Custom marker file to check if modifications have been made
set(MARKER_FILE "${antlrsrc_SOURCE_DIR}/antlr_patched.marker")
# Fetch and modify only once
if(NOT EXISTS ${MARKER_FILE})
message(STATUS "Modifying ANTLR sources")
# Add needed include file for CharScanner.hpp
# Comment out use of std::binary_function, deprecated in C++11 and removed in C++17
set(CHARSCANNER_HPP "${antlrsrc_SOURCE_DIR}/lib/cpp/antlr/CharScanner.hpp")
file(READ ${CHARSCANNER_HPP} FILE_CONTENTS)
string(REPLACE "#include <antlr/config.hpp>\n\n" "#include <antlr/config.hpp>\n#include <string.h>\n\n" FILE_CONTENTS "${FILE_CONTENTS}")
string(REPLACE "class ANTLR_API CharScannerLiteralsLess : public ANTLR_USE_NAMESPACE(std)binary_function<ANTLR_USE_NAMESPACE(std)string,ANTLR_USE_NAMESPACE(std)string,bool>"
"class ANTLR_API CharScannerLiteralsLess /* : public ANTLR_USE_NAMESPACE(std)binary_function<ANTLR_USE_NAMESPACE(std)string,ANTLR_USE_NAMESPACE(std)string,bool> */" FILE_CONTENTS "${FILE_CONTENTS}")
file(WRITE ${CHARSCANNER_HPP} "${FILE_CONTENTS}")
# Remove pragma warning disable that is no longer valid
set(CONFIG_HPP "${antlrsrc_SOURCE_DIR}/lib/cpp/antlr/config.hpp")
file(READ ${CONFIG_HPP} FILE_CONTENTS)
string(REPLACE "# pragma warning( disable : 4786 4231 )" "# pragma warning( disable : 4786 )" FILE_CONTENTS "${FILE_CONTENTS}")
file(WRITE ${CONFIG_HPP} "${FILE_CONTENTS}")
# Create marker file to indicate that modifications have been done
file(WRITE ${MARKER_FILE} "Patched ANTLR sources.")
endif()
# antlr library
add_library(antlr OBJECT)
set_target_properties(antlr PROPERTIES POSITION_INDEPENDENT_CODE ON)
file(GLOB ANTLR_SOURCE ${antlrsrc_SOURCE_DIR}/lib/cpp/src/*.cpp)
list(REMOVE_ITEM ANTLR_SOURCE "${antlrsrc_SOURCE_DIR}/lib/cpp/src/dll.cpp")
target_sources(antlr PRIVATE "${ANTLR_SOURCE}")
target_include_directories(antlr SYSTEM PUBLIC "${antlrsrc_SOURCE_DIR}/lib/cpp/" SYSTEM PRIVATE "${antlrsrc_SOURCE_DIR}/lib/cpp/")
target_compile_options(antlr PRIVATE ${SRCML_ANTLR_COMPILE_FLAGS})
# Enable proper exception catching when building for wasm
if(${CMAKE_SYSTEM_NAME} STREQUAL "Emscripten")
add_compile_options(-fwasm-exceptions)
endif()
# Generated source from antlr and the parser
set(CMAKE_GENERATED_SOURCE_DIR ${CMAKE_BINARY_DIR}/parser)
# Find antlr runtime
set(ANTLR_EXE ${Java_JAVA_EXECUTABLE} -classpath "${antlrsrc_SOURCE_DIR}/antlr.jar" antlr.Tool)
message("-- ANTLR: ${ANTLR_EXE}")
# parser library
file(GLOB PARSER_SOURCE *.hpp *.cpp)
add_library(parser OBJECT
${CMAKE_GENERATED_SOURCE_DIR}/srcMLParser.cpp
${CMAKE_GENERATED_SOURCE_DIR}/KeywordLexer.cpp
${CMAKE_GENERATED_SOURCE_DIR}/CommentTextLexer.cpp
${PARSER_SOURCE}
)
set_target_properties(parser PROPERTIES POSITION_INDEPENDENT_CODE ON)
target_include_directories(parser SYSTEM PUBLIC ${antlrsrc_SOURCE_DIR}/lib/cpp)
target_include_directories(parser PRIVATE . ${CMAKE_GENERATED_SOURCE_DIR} PUBLIC . SYSTEM PUBLIC ${CMAKE_GENERATED_SOURCE_DIR})
target_link_libraries(parser PRIVATE LibXml2::LibXml2 antlr)
target_include_directories(parser PRIVATE $<TARGET_PROPERTY:TinySHA1,INTERFACE_INCLUDE_DIRECTORIES>)
if(SRCML_DEBUG_PARSER)
set_source_files_properties(${CMAKE_GENERATED_SOURCE_DIR}/srcMLParser.cpp PROPERTIES COMPILE_DEFINITIONS SRCML_DEBUG_PARSER)
endif()
# PreCompiled Headers configuration of the parser
if (SRCML_PARSER_PCH)
target_precompile_headers(parser PRIVATE "${SRCML_PARSER_PCH}")
endif()
target_compile_options(antlr PRIVATE ${SRCML_ANTLR_DISABLED_WARNINGS})
target_compile_options(parser PRIVATE ${SRCML_PARSER_DISABLED_WARNINGS})
#
# RunAntlr
# Executes ANTLR executable on the provided files.
#
# Takes 3 parameters OUTPUT_FILES INPUT_FILES DEPENDENCIES and
# 1 optional parameter INCLUDE_GRAMMAR
# Use with named arguments.
#
function(RunAntlr OUTPUT_FILES INPUT_FILES DEPENDENCIES INCLUDE_GRAMMAR)
add_custom_command(OUTPUT ${OUTPUT_FILES}
DEPENDS ${INPUT_FILES} ${DEPENDENCIES}
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
COMMAND ${ANTLR_EXE} -o \"${CMAKE_GENERATED_SOURCE_DIR}\" -glib "\"${INCLUDE_GRAMMAR}\"" ${INPUT_FILES}
COMMAND ${CMAKE_COMMAND} -E touch ${OUTPUT_FILES}
)
endfunction(RunAntlr)
macro(lexerFiles LEXER)
set(${LEXER}LexerOutputFiles
${CMAKE_GENERATED_SOURCE_DIR}/${LEXER}Lexer.cpp
${CMAKE_GENERATED_SOURCE_DIR}/${LEXER}Lexer.hpp
${CMAKE_GENERATED_SOURCE_DIR}/${LEXER}LexerTokenTypes.hpp
${CMAKE_GENERATED_SOURCE_DIR}/${LEXER}LexerTokenTypes.txt
${CMAKE_GENERATED_SOURCE_DIR}/expanded${LEXER}Lexer.g
)
endmacro()
# Running ANTLR on CommentTextLexer.g
lexerFiles(CommentText)
RunAntlr("${CommentTextLexerOutputFiles}"
CommentTextLexer.g
""
""
)
# Running ANTLR on TextLexer.g
lexerFiles(Text)
RunAntlr("${TextLexerOutputFiles}"
TextLexer.g
${CMAKE_GENERATED_SOURCE_DIR}/CommentTextLexer.cpp
""
)
# Running ANTLR on OperatorLexer.g
lexerFiles(Operator)
RunAntlr("${OperatorLexerOutputFiles}"
OperatorLexer.g
${CMAKE_GENERATED_SOURCE_DIR}/TextLexer.cpp
TextLexer.g
)
# Running ANTLR on KeywordLexer.g
lexerFiles(Keyword)
RunAntlr("${KeywordLexerOutputFiles}"
KeywordLexer.g
${CMAKE_GENERATED_SOURCE_DIR}/OperatorLexer.cpp
"OperatorLexer.g;TextLexer.g"
)
# Running ANTLR on srcMLParser.g
set(srcMLParserOutputFiles
${CMAKE_GENERATED_SOURCE_DIR}/srcMLParser.cpp
${CMAKE_GENERATED_SOURCE_DIR}/srcMLParser.hpp
${CMAKE_GENERATED_SOURCE_DIR}/srcMLParserTokenTypes.hpp
${CMAKE_GENERATED_SOURCE_DIR}/srcMLParserTokenTypes.txt
)
RunAntlr("${srcMLParserOutputFiles}"
srcMLParser.g
"srcMLParser.g;${CMAKE_GENERATED_SOURCE_DIR}/KeywordLexer.cpp"
"OperatorLexer.g;KeywordLexer.g;TextLexer.g"
)