Repository navigation
Expand file tree
/
Copy pathstrings.nix
More file actions
3161 lines (2447 loc) · 64.5 KB
/
Copy pathstrings.nix
File metadata and controls
3161 lines (2447 loc) · 64.5 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/**
String manipulation functions.
*/
{ lib }:
let
inherit (builtins) length;
inherit (lib.trivial) warnIf;
asciiTable = import ./ascii-table.nix;
in
rec {
inherit (builtins)
compareVersions
elem
elemAt
filter
fromJSON
genList
head
isInt
isList
isAttrs
isPath
isString
match
parseDrvName
readFile
replaceStrings
split
storeDir
stringLength
substring
tail
toJSON
typeOf
unsafeDiscardStringContext
appendContext
;
/**
Concatenates a list of strings with a separator between each element.
# Inputs
`sep`
: Separator to add between elements
`list`
: List of strings that will be joined
# Type
```
join :: String -> [String] -> String
```
# Examples
:::{.example}
## `lib.strings.join` usage example
```nix
join ", " ["foo" "bar"]
=> "foo, bar"
```
:::
*/
join = builtins.concatStringsSep;
/**
Concatenate a list of strings.
# Type
```
concatStrings :: [String] -> String
```
# Examples
:::{.example}
## `lib.strings.concatStrings` usage example
```nix
concatStrings ["foo" "bar"]
=> "foobar"
```
:::
*/
concatStrings = builtins.concatStringsSep "";
/**
Map a function over a list and concatenate the resulting strings.
# Inputs
`f`
: 1\. Function argument
`list`
: 2\. Function argument
# Type
```
concatMapStrings :: (a -> String) -> [a] -> String
```
# Examples
:::{.example}
## `lib.strings.concatMapStrings` usage example
```nix
concatMapStrings (x: "a" + x) ["foo" "bar"]
=> "afooabar"
```
:::
*/
concatMapStrings = f: list: concatStrings (map f list);
/**
Like `concatMapStrings` except that the function `f` also gets the
position as a parameter.
# Inputs
`f`
: 1\. Function argument
`list`
: 2\. Function argument
# Type
```
concatImapStrings :: (Int -> a -> String) -> [a] -> String
```
# Examples
:::{.example}
## `lib.strings.concatImapStrings` usage example
```nix
concatImapStrings (pos: x: "${toString pos}-${x}") ["foo" "bar"]
=> "1-foo2-bar"
```
:::
*/
concatImapStrings = f: list: concatStrings (lib.imap1 f list);
/**
Place an element between each element of a list
# Inputs
`separator`
: Separator to add between elements
`list`
: Input list
# Type
```
intersperse :: a -> [a] -> [a]
```
# Examples
:::{.example}
## `lib.strings.intersperse` usage example
```nix
intersperse "/" ["usr" "local" "bin"]
=> ["usr" "/" "local" "/" "bin"].
```
:::
*/
intersperse =
separator: list:
if list == [ ] || length list == 1 then
list
else
tail (
lib.concatMap (x: [
separator
x
]) list
);
/**
Concatenate a list of strings with a separator between each element
# Inputs
`sep`
: Separator to add between elements
`list`
: List of input strings
# Type
```
concatStringsSep :: String -> [String] -> String
```
# Examples
:::{.example}
## `lib.strings.concatStringsSep` usage example
```nix
concatStringsSep "/" ["usr" "local" "bin"]
=> "usr/local/bin"
```
:::
*/
concatStringsSep = builtins.concatStringsSep;
/**
Maps a function over a list of strings and then concatenates the
result with the specified separator interspersed between
elements.
# Inputs
`sep`
: Separator to add between elements
`f`
: Function to map over the list
`list`
: List of input strings
# Type
```
concatMapStringsSep :: String -> (a -> String) -> [a] -> String
```
# Examples
:::{.example}
## `lib.strings.concatMapStringsSep` usage example
```nix
concatMapStringsSep "-" (x: toUpper x) ["foo" "bar" "baz"]
=> "FOO-BAR-BAZ"
```
:::
*/
concatMapStringsSep =
sep: f: list:
concatStringsSep sep (map f list);
/**
Same as `concatMapStringsSep`, but the mapping function
additionally receives the position of its argument.
# Inputs
`sep`
: Separator to add between elements
`f`
: Function that receives elements and their positions
`list`
: List of input strings
# Type
```
concatIMapStringsSep :: String -> (Int -> a -> String) -> [a] -> String
```
# Examples
:::{.example}
## `lib.strings.concatImapStringsSep` usage example
```nix
concatImapStringsSep "-" (pos: x: toString (x / pos)) [ 6 6 6 ]
=> "6-3-2"
```
:::
*/
concatImapStringsSep =
sep: f: list:
concatStringsSep sep (lib.imap1 f list);
/**
Like [`concatMapStringsSep`](#function-library-lib.strings.concatMapStringsSep)
but takes an attribute set instead of a list.
# Inputs
`sep`
: Separator to add between item strings
`f`
: Function that takes each key and value and return a string
`attrs`
: Attribute set to map from
# Type
```
concatMapAttrsStringSep :: String -> (String -> a -> String) -> { [String] :: a } -> String
```
# Examples
:::{.example}
## `lib.strings.concatMapAttrsStringSep` usage example
```nix
concatMapAttrsStringSep "\n" (name: value: "${name}: foo-${value}") { a = "0.1.0"; b = "0.2.0"; }
=> "a: foo-0.1.0\nb: foo-0.2.0"
```
:::
*/
concatMapAttrsStringSep =
sep: f: attrs:
concatStringsSep sep (lib.attrValues (lib.mapAttrs f attrs));
/**
Concatenate a list of strings, adding a newline at the end of each one.
# Inputs
`list`
: List of strings. Any element that is not a string will be implicitly converted to a string.
# Type
```
concatLines :: [String] -> String
```
# Examples
:::{.example}
## `lib.strings.concatLines` usage example
```nix
concatLines [ "foo" "bar" ]
=> "foo\nbar\n"
```
:::
*/
concatLines = lines: optionalString (lines != [ ]) (concatStringsSep "\n" lines + "\n");
/**
Given string `s`, replace every occurrence of the string `from` with the string `to`.
# Inputs
`from`
: The string to be replaced
`to`
: The string to replace with
`s`
: The original string where replacements will be made
# Type
```
replaceString :: String -> String -> String -> String
```
# Examples
:::{.example}
## `lib.strings.replaceString` usage example
```nix
replaceString "world" "Nix" "Hello, world!"
=> "Hello, Nix!"
replaceString "." "_" "v1.2.3"
=> "v1_2_3"
```
:::
*/
replaceString = from: to: replaceStrings [ from ] [ to ];
/**
Repeat a string `n` times,
and concatenate the parts into a new string.
# Inputs
`n`
: 1\. Function argument
`s`
: 2\. Function argument
# Type
```
replicate :: Int -> String -> String
```
# Examples
:::{.example}
## `lib.strings.replicate` usage example
```nix
replicate 3 "v"
=> "vvv"
replicate 5 "hello"
=> "hellohellohellohellohello"
```
:::
*/
replicate = n: s: concatStrings (lib.lists.replicate n s);
/**
Remove leading and trailing whitespace from a string `s`.
Whitespace is defined as any of the following characters:
" ", "\t" "\r" "\n"
# Inputs
`s`
: The string to trim
# Type
```
trim :: String -> String
```
# Examples
:::{.example}
## `lib.strings.trim` usage example
```nix
trim " hello, world! "
=> "hello, world!"
```
:::
*/
trim = trimWith {
start = true;
end = true;
};
/**
Remove leading and/or trailing whitespace from a string `s`.
To remove both leading and trailing whitespace, you can also use [`trim`](#function-library-lib.strings.trim)
Whitespace is defined as any of the following characters:
" ", "\t" "\r" "\n"
# Inputs
`config` (Attribute set)
: `start`
: Whether to trim leading whitespace (`false` by default)
: `end`
: Whether to trim trailing whitespace (`false` by default)
`s`
: The string to trim
# Type
```
trimWith :: { start :: Bool; end :: Bool; } -> String -> String
```
# Examples
:::{.example}
## `lib.strings.trimWith` usage example
```nix
trimWith { start = true; } " hello, world! "}
=> "hello, world! "
trimWith { end = true; } " hello, world! "}
=> " hello, world!"
```
:::
*/
trimWith =
{
start ? false,
end ? false,
}:
let
# Define our own whitespace character class instead of using
# `[:space:]`, which is not well-defined.
chars = " \t\r\n";
# To match up until trailing whitespace, we need to capture a
# group that ends with a non-whitespace character.
regex =
if start && end then
"[${chars}]*(.*[^${chars}])[${chars}]*"
else if start then
"[${chars}]*(.*)"
else if end then
"(.*[^${chars}])[${chars}]*"
else
"(.*)";
in
s:
let
# If the string was empty or entirely whitespace,
# then the regex may not match and `res` will be `null`.
res = match regex s;
in
optionalString (res != null) (head res);
/**
Construct a Unix-style, colon-separated search path consisting of
the given `subDir` appended to each of the given paths.
# Inputs
`subDir`
: Directory name to append
`paths`
: List of base paths
# Type
```
makeSearchPath :: String -> [String] -> String
```
# Examples
:::{.example}
## `lib.strings.makeSearchPath` usage example
```nix
makeSearchPath "bin" ["/root" "/usr" "/usr/local"]
=> "/root/bin:/usr/bin:/usr/local/bin"
makeSearchPath "bin" [""]
=> "/bin"
```
:::
*/
makeSearchPath =
subDir: paths: concatStringsSep ":" (map (path: path + "/" + subDir) (filter (x: x != null) paths));
/**
Construct a Unix-style search path by appending the given
`subDir` to the specified `output` of each of the packages.
If no output by the given name is found, fallback to `.out` and then to
the default.
# Inputs
`output`
: Package output to use
`subDir`
: Directory name to append
`pkgs`
: List of packages
# Type
```
makeSearchPathOutput :: String -> String -> [Derivation] -> String
```
# Examples
:::{.example}
## `lib.strings.makeSearchPathOutput` usage example
```nix
makeSearchPathOutput "dev" "bin" [ pkgs.openssl pkgs.zlib ]
=> "/nix/store/9rz8gxhzf8sw4kf2j2f1grr49w8zx5vj-openssl-1.0.1r-dev/bin:/nix/store/wwh7mhwh269sfjkm6k5665b5kgp7jrk2-zlib-1.2.8/bin"
```
:::
*/
makeSearchPathOutput =
output: subDir: pkgs:
makeSearchPath subDir (map (lib.getOutput output) pkgs);
/**
Construct a library search path (such as RPATH) containing the
libraries for a set of packages
# Inputs
`packages`
: List of packages
# Type
```
makeLibraryPath :: [Derivation] -> String
```
# Examples
:::{.example}
## `lib.strings.makeLibraryPath` usage example
```nix
makeLibraryPath [ "/usr" "/usr/local" ]
=> "/usr/lib:/usr/local/lib"
pkgs = import <nixpkgs> { }
makeLibraryPath [ pkgs.openssl pkgs.zlib ]
=> "/nix/store/9rz8gxhzf8sw4kf2j2f1grr49w8zx5vj-openssl-1.0.1r/lib:/nix/store/wwh7mhwh269sfjkm6k5665b5kgp7jrk2-zlib-1.2.8/lib"
```
:::
*/
makeLibraryPath = makeSearchPathOutput "lib" "lib";
/**
Construct an include search path (such as C_INCLUDE_PATH) containing the
header files for a set of packages or paths.
# Inputs
`packages`
: List of packages
# Type
```
makeIncludePath :: [Derivation] -> String
```
# Examples
:::{.example}
## `lib.strings.makeIncludePath` usage example
```nix
makeIncludePath [ "/usr" "/usr/local" ]
=> "/usr/include:/usr/local/include"
pkgs = import <nixpkgs> { }
makeIncludePath [ pkgs.openssl pkgs.zlib ]
=> "/nix/store/9rz8gxhzf8sw4kf2j2f1grr49w8zx5vj-openssl-1.0.1r-dev/include:/nix/store/wwh7mhwh269sfjkm6k5665b5kgp7jrk2-zlib-1.2.8-dev/include"
```
:::
*/
makeIncludePath = makeSearchPathOutput "dev" "include";
/**
Construct a binary search path (such as $PATH) containing the
binaries for a set of packages.
# Inputs
`packages`
: List of packages
# Type
```
makeBinPath :: [Derivation] -> String
```
# Examples
:::{.example}
## `lib.strings.makeBinPath` usage example
```nix
makeBinPath ["/root" "/usr" "/usr/local"]
=> "/root/bin:/usr/bin:/usr/local/bin"
```
:::
*/
makeBinPath = makeSearchPathOutput "bin" "bin";
/**
Normalize path, removing extraneous /s
# Inputs
`s`
: 1\. Function argument
# Type
```
normalizePath :: String -> String
```
# Examples
:::{.example}
## `lib.strings.normalizePath` usage example
```nix
normalizePath "/a//b///c/"
=> "/a/b/c/"
```
:::
*/
normalizePath =
s:
warnIf (isPath s)
''
lib.strings.normalizePath: The argument (${toString s}) is a path value, but only strings are supported.
Path values are always normalised in Nix, so there's no need to call this function on them.
This function also copies the path to the Nix store and returns the store path, the same as "''${path}" will, which may not be what you want.
This behavior is deprecated and will throw an error in the future.''
(
builtins.foldl' (x: y: if y == "/" && hasSuffix "/" x then x else x + y) "" (stringToCharacters s)
);
/**
Depending on the boolean `cond`, return either the given string
or the empty string. Useful to concatenate against a bigger string.
# Inputs
`cond`
: Condition
`string`
: String to return if condition is true
# Type
```
optionalString :: Bool -> String -> String
```
# Examples
:::{.example}
## `lib.strings.optionalString` usage example
```nix
optionalString true "some-string"
=> "some-string"
optionalString false "some-string"
=> ""
```
:::
*/
optionalString = cond: string: if cond then string else "";
/**
Determine whether a string has given prefix.
# Inputs
`pref`
: Prefix to check for
`str`
: Input string
# Type
```
hasPrefix :: String -> String -> Bool
```
# Examples
:::{.example}
## `lib.strings.hasPrefix` usage example
```nix
hasPrefix "foo" "foobar"
=> true
hasPrefix "foo" "barfoo"
=> false
```
:::
*/
hasPrefix =
pref: str:
# Before 23.05, paths would be copied to the store before converting them
# to strings and comparing. This was surprising and confusing.
warnIf (isPath pref)
''
lib.strings.hasPrefix: The first argument (${toString pref}) is a path value, but only strings are supported.
There is almost certainly a bug in the calling code, since this function always returns `false` in such a case.
This function also copies the path to the Nix store, which may not be what you want.
This behavior is deprecated and will throw an error in the future.
You might want to use `lib.path.hasPrefix` instead, which correctly supports paths.''
(substring 0 (stringLength pref) str == pref);
/**
Determine whether a string has given suffix.
# Inputs
`suffix`
: Suffix to check for
`content`
: Input string
# Type
```
hasSuffix :: String -> String -> Bool
```
# Examples
:::{.example}
## `lib.strings.hasSuffix` usage example
```nix
hasSuffix "foo" "foobar"
=> false
hasSuffix "foo" "barfoo"
=> true
```
:::
*/
hasSuffix =
suffix: content:
let
lenContent = stringLength content;
lenSuffix = stringLength suffix;
in
# Before 23.05, paths would be copied to the store before converting them
# to strings and comparing. This was surprising and confusing.
warnIf (isPath suffix)
''
lib.strings.hasSuffix: The first argument (${toString suffix}) is a path value, but only strings are supported.
There is almost certainly a bug in the calling code, since this function always returns `false` in such a case.
This function also copies the path to the Nix store, which may not be what you want.
This behavior is deprecated and will throw an error in the future.''
(lenContent >= lenSuffix && substring (lenContent - lenSuffix) lenContent content == suffix);
/**
Determine whether a string contains the given infix
# Inputs
`infix`
: 1\. Function argument
`content`
: 2\. Function argument
# Type
```
hasInfix :: String -> String -> Bool
```
# Examples
:::{.example}
## `lib.strings.hasInfix` usage example
```nix
hasInfix "bc" "abcd"
=> true
hasInfix "ab" "abcd"
=> true
hasInfix "cd" "abcd"
=> true
hasInfix "foo" "abcd"
=> false
```
:::
*/
hasInfix =
infix: content:
# Before 23.05, paths would be copied to the store before converting them
# to strings and comparing. This was surprising and confusing.
warnIf (isPath infix)
''
lib.strings.hasInfix: The first argument (${toString infix}) is a path value, but only strings are supported.
There is almost certainly a bug in the calling code, since this function always returns `false` in such a case.
This function also copies the path to the Nix store, which may not be what you want.
This behavior is deprecated and will throw an error in the future.''
(builtins.match ".*${escapeRegex infix}.*" "${content}" != null);
/**
Convert a string `s` to a list of characters (i.e. singleton strings).
This allows you to, e.g., map a function over each character. However,
note that this will likely be horribly inefficient; Nix is not a
general purpose programming language. Complex string manipulations
should, if appropriate, be done in a derivation.
Also note that Nix treats strings as a list of bytes and thus doesn't
handle unicode.
# Inputs
`s`
: 1\. Function argument
# Type
```
stringToCharacters :: String -> [String]
```
# Examples
:::{.example}
## `lib.strings.stringToCharacters` usage example
```nix
stringToCharacters ""
=> [ ]
stringToCharacters "abc"
=> [ "a" "b" "c" ]
stringToCharacters "🦄"
=> [ "�" "�" "�" "�" ]
```
:::
*/
stringToCharacters = s: genList (p: substring p 1 s) (stringLength s);
/**
Manipulate a string character by character and replace them by
strings before concatenating the results.
# Inputs
`f`
: Function to map over each individual character
`s`
: Input string
# Type
```
stringAsChars :: (String -> String) -> String -> String
```
# Examples
:::{.example}
## `lib.strings.stringAsChars` usage example
```nix
stringAsChars (x: if x == "a" then "i" else x) "nax"
=> "nix"
```
:::
*/
stringAsChars =
# Function to map over each individual character
f:
# Input string
s:
concatStrings (map f (stringToCharacters s));
/**
Convert char to ascii value, must be in printable range
# Inputs
`c`
: 1\. Function argument
# Type
```
charToInt :: String -> Int
```
# Examples
:::{.example}
## `lib.strings.charToInt` usage example
```nix
charToInt "A"
=> 65
charToInt "("
=> 40
```