Repository navigation
Expand file tree
/
Copy pathsettings.gradle
More file actions
41 lines (37 loc) · 1.53 KB
/
Copy pathsettings.gradle
File metadata and controls
41 lines (37 loc) · 1.53 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
include ':TMessagesProj'
include ':TMessagesProj_App'
include ':TMessagesProj_AppTests'
include ':TMessagesProj_PluginTor'
// Since 12.10.0 TMessagesProj depends on `project(':jlatexmath')`, which lives
// in the TMessagesProj/lib/jlatexmath submodule. Upstream never declares the
// project, so its own settings.gradle does not configure as shipped. Settings
// are evaluated before any task runs, so patchNativeSources cannot init this
// one: do it here, otherwise a fresh clone fails with an unexplained missing
// project directory.
def jlatexmathDir = file('TMessagesProj/lib/jlatexmath/jlatexmath')
if (!jlatexmathDir.exists()) {
exec {
workingDir rootDir
commandLine 'git', 'submodule', 'update', '--init', 'TMessagesProj/lib/jlatexmath'
}
}
include ':jlatexmath'
project(':jlatexmath').projectDir = jlatexmathDir
// Same for the androidx media3 fork: since 12.10.2 upstream applies its
// core_settings.gradle from the TMessagesProj_Modules/media submodule, at
// settings-evaluation time, so a fresh clone cannot even configure without it.
def mediaModuleDir = file('TMessagesProj_Modules/media')
if (!file("$mediaModuleDir/core_settings.gradle").exists()) {
exec {
workingDir rootDir
commandLine 'git', 'submodule', 'update', '--init', 'TMessagesProj_Modules/media'
}
}
dependencyResolutionManagement {
repositories {
google()
mavenCentral()
}
}
gradle.ext.androidxMediaModulePrefix = 'TMessagesProj_Modules:media3:media-'
apply from: file("$mediaModuleDir/core_settings.gradle")