# gnuplot script for plotting eurofxref-hist.csv as obtained from
#  http://www.ecb.int/stats/exchange/eurofxref/html/index.en.html

# download and unzip data if not available - delete eurofxref* to force new download.
# remove or comment out these lines in Windows/MacOS.
! [ -f eurofxref-hist.csv ] || wget http://www.ecb.int/stats/eurofxref/eurofxref-hist.zip
! [ -f eurofxref-hist.csv ] || unzip eurofxref-hist.zip

#input
set timefmt "%Y-%m-%d"
set datafile missing 'N/A'
set datafile separator ','

#output
set key top left
set style data lines
set grid

set xdata time
set format x '%Y'
set xrange ['2005-01-01':*]
set xtics 31536000
set mxtics 12
#set xlabel 'Date'

set ylabel 'THB'
set format y '%.0f'

## gnuplot for SVG - gnuplot 4.2 / Ubuntu 8.10 
set term svg size 800,400 font "Arial,10"

set outp 'Euro exchange rate to THB.svg'
set style line 1 lt rgb 'blue' lw 1

#available currencies:
#first one is $2, second $3 and so on
#USD,JPY,BGN,CYP,CZK,DKK,EEK,GBP,HUF,LTL,LVL,MTL,PLN,ROL,RON,SEK,SIT,SKK,CHF,ISK,
#NOK,HRK,RUB,TRL,TRY,AUD,BRL,CAD,CNY,HKD,IDR,INR,KRW,MXN,MYR,NZD,PHP,SGD,THB,ZAR																				

plot 'eurofxref-hist.csv' usi 1:($40) title '1 Euro in THB' ls 1